Components

1. ESP8266 Development Board (such as NodeMCU) (Affiliate) – https://s.click.aliexpress.com/e/_DD3JQhj
2. Breadboard and jumper wires (Affiliate) – https://s.click.aliexpress.com/e/_Dl5kuk1
3. DHT11 temperature and humidity sensor (Affiliate) – https://s.click.aliexpress.com/e/_DFb2JzR
4. 1x 10k Ohm resistor

Wiring

1. Connect the DHT11 sensor to the master ESP8266 module:
   • VCC pin to 3.3V
   • GND pin to GND
   • Data pin to D2 (GPIO4) with a 10k Ohm pull-up resistor between VCC and Data pin
2. Connect both ESP8266 modules to your computer using USB-to-serial converters for programming.

Install the required libraries in the Arduino IDE:

• • ESP8266 core for Arduino -> My Link to a post that explains this in depth
  • Adafruit DHT sensor library

Sender Code

#include <ESP8266WiFi.h>
#include <espnow.h>
#include <DHT.h>

#define DHTPIN D2
#define DHTTYPE DHT11

DHT dht(DHTPIN, DHTTYPE);

uint8_t receiverMAC[] = { 0x8C, 0xAA, 0xB5, 0x0D, 0x44, 0xCE };  // Replace with the receiver's MAC address

typedef struct {
  float temperature;
  float humidity;
} SensorData;

SensorData sensorData;

void setup() {
  Serial.begin(115200);
  dht.begin();
  WiFi.mode(WIFI_STA);
  WiFi.disconnect();
  if (esp_now_init() == 0) {
    Serial.println("ESP-NOW Initialized");
    esp_now_set_self_role(ESP_NOW_ROLE_CONTROLLER);
    esp_now_add_peer(receiverMAC, ESP_NOW_ROLE_SLAVE, 1, NULL, 0);
    esp_now_register_send_cb([](uint8_t* mac, uint8_t sendStatus) {
      Serial.print("Send status: ");
      Serial.println(sendStatus == 0 ? "Success" : "Failed");
    });
  } else {
    Serial.println("ESP-NOW Initialization Failed");
    ESP.restart();
  }
}

void loop() {
  sensorData.temperature = dht.readTemperature();
  sensorData.humidity = dht.readHumidity();
  esp_now_send(receiverMAC, (uint8_t*)&sensorData, sizeof(sensorData));
  delay(2000);
}

Receiver Code

#include <ESP8266WiFi.h>
#include <espnow.h>

typedef struct struct_message {
  float temperature;
  float humidity;
} struct_message;

struct_message receivedData;


void dataReceived(uint8_t *senderMac, uint8_t *incomingData, uint8_t len) {
  memcpy(&receivedData, incomingData, sizeof(receivedData));
  Serial.print("Temperature: ");
  Serial.print(receivedData.temperature);
  Serial.print(" °C, Humidity: ");
  Serial.print(receivedData.humidity);
  Serial.println(" %");
}

void setup() {
  Serial.begin(115200);
  WiFi.mode(WIFI_STA);
  WiFi.disconnect();
  if (esp_now_init() == 0) {
    Serial.println("ESP-NOW Initialized.");
    esp_now_set_self_role(ESP_NOW_ROLE_SLAVE);
    esp_now_register_recv_cb(dataReceived);
  } else {
    Serial.println("ESP-NOW Initialization Failed.");
    ESP.restart();
  }
}

void loop() {
}

• Don’t forget to define the MAC Address of your Receiver in the funtion -> #define RECEIVER_ADDRESS {0x24, 0x0A, 0xC4, 0x7E, 0x18, 0x2C}

Testing

Conclusion